Using VBScript and WMI to change master IP on secondary zone

Our primary DNS server changed it's IP yesterday and we had a secondary DNS server with several domains that needed to have the IP for the master server updated. Windows' gift and curse is that you don't have a bunch of text files where you can find everything but manually opening the properties of every domain, removing the previous master IP, adding a new IP and moving on to the next domain was just not an option.

That's why we have Windows Management Instrumentation (WMI). For an administrator it's the best thing that's happened since they started slicing bread. Well, not quite, but if you intend to do some serious administration of Windows servers you'd better look into it. If you don't like looking through a bunch of documentation for figure out what to do, use Scriptomatic 2.0 like I did yesterday. It will generate a basic script for you that can easily be modified.

Now, the main event: a script to update the master server IP for all secondary DNS zones on a Windows computer.

1. ' This script updates the Master server IP for all secondary zones on the
2. ' specifed computers.
3.  
4. ' Constants for WMI
5. Const wbemFlagReturnWhenComplete = &H0
6. Const wbemFlagReturnImmediately = &h10
7. Const wbemFlagForwardOnly = &h20
8. Const iDnsSecondary = 2
9.  
10.  
11. ' The array to hold the master servers
12. ' (there can be multiple master servers)
13. Dim MasterServersArray(0)
14. ' Add the master servers to the array. Replace with your own IP
15. MasterServersArray(0) = "192.168.2.10"
16.  
17. ' The address of the old master server, replace with your own IP
18. ' Used to check the zone and only update those that need it.
19. Dim strOldMasterServer
20. strOldMasterServer = "10.0.0.10"
22. ' The script can do this on multiple computers,
23. ' just add them to the array
24. Dim arrComputers
25. arrComputers = Array("COMPUTERNAME")
26.  
27. Dim objWMIService
28. Dim colItems
29. Dim objItem
30.  
31. For Each strComputer In arrComputers
32.         WScript.Echo
33.         WScript.Echo "=========================================="
34.         WScript.Echo "Computer: " & strComputer
35.         WScript.Echo "=========================================="
36.        
37.         WScript.Echo "Fetching zones..."
38.         ' Connect to the DNS WMI interface on the current computer
39.         Set objWMIService = GetObject("winmgmts:\\" & strComputer _
40.                 & "\root\MicrosoftDNS")
41.  
42.         ' Get all zones from the DNS server. We use wbemFlagReturnWhenComplete
43.         ' to make sure the call completes before returning. If not we often get
44.         ' errors when looping through the returned collection. If you only want 
45.         ' some zones to be updated you can filter your query just like any SQL query.
46.         Set colItems = objWMIService.ExecQuery("SELECT * FROM MicrosoftDNS_Zone", _
47.                 "WQL", wbemFlagReturnWhenComplete + wbemFlagForwardOnly)
48.         WScript.Echo "Retrieved zones."
49.  
50.         ' Used to hold a return object.
51.         dim objTmp
52.  
53.         For Each objItem In colItems
54.           ' Only secondary zones have master servers
55.           if objItem.ZoneType = iDnsSecondary then     
56.                 ' Get the current master IPs 
57.                         strMastersIPAddressesArray = Join(objItem.MastersIPAddressesArray, ",")
58.                        
59.                         ' Some information
60.                         WScript.Echo "Name: " & objItem.Name
61.                         WScript.Echo "MastersIPAddressesArray: " & strMastersIPAddressesArray
62.  
63.                         ' We'll only do this in the zones with the old master server
64.                         ' No need to update zones that don't need it.
65.                         if strMastersIPAddressesArray = strOldMasterServer then
66.                           ' ResetMasterIpArray is a function on the WMI object
67.                           ' that replacesthe current array of Master IPs.
68.                           ' objTemp receives a refrence to the updated zone.
69.                           objItem.ResetMasterIpArray MasterServersArray, objTemp
70.                           ' We don't need it so we set it to nothing
71.                           ' immediatly to save memory
72.                           set objTemp = nothing
73.                           WScript.Echo
74.                         end If
75.                         ' Let's just make the secondary zone refresh from
76.                         ' the master server while we're at it
77.                         objItem.ForceRefreshOfSecondaryZoneFromMaster()
78.           end if
79.         Next
80. Next